final: prev: {
  openrgb = final.callPackage ./openrgb/package.nix { openrgb = prev.openrgb; };
  apple-fonts.sf-pro = final.stdenvNoCC.mkDerivation {
    pname = "sf-pro";
    version = "latest";

    src = prev.fetchurl {
      url = "https://devimages-cdn.apple.com/design/resources/download/SF-Pro.dmg";
      sha256 = "Lk14U5iLc03BrzO5IdjUwORADqwxKSSg6rS3OlH9aa4=";
    };

    nativeBuildInputs = [
      prev.undmg
      prev.p7zip
    ];

    unpackPhase = ''
      runHook preUnpack
      undmg "$src"
      7z x "SF Pro Fonts.pkg"
      7z x "Payload~"
      runHook postUnpack
    '';

    installPhase = ''
      runHook preInstall

      mkdir -p $out/share/fonts/opentype
      mkdir -p $out/share/fonts/truetype

      find . -name '*.otf' -exec mv {} $out/share/fonts/opentype/ \;
      find . -name '*.ttf' -exec mv {} $out/share/fonts/truetype/ \;

      runHook postInstall
    '';

    meta = with prev.lib; {
      description = "Apple SF Pro font family";
      platforms = platforms.all;
    };
  };

}