{
  config,
  lib,
  pkgs,
  modulesPath,
  ...
}:

{
  imports = [
    (modulesPath + "/installer/scan/not-detected.nix")
    ./persephone/hardware.nix
    ./persephone/networking.nix
    ../profiles/minimal.linux.nix
    ../profiles/desktop.linux.nix
  ];

  boot = {
    extraModulePackages = [ ];
    kernelModules = [ "kvm-intel" ];
    kernelPackages = pkgs.linuxPackages_6_17;
    kernelParams = [ "i915.enable_guc=3" ];
  };
  boot.initrd.availableKernelModules = [
    "xhci_pci"
    "thunderbolt"
    "nvme"
    "ahci"
    "usbhid"
    "sd_mod"
  ];

  console = {
    keyMap = "us";
    font = "${pkgs.terminus_font}/share/consolefonts/ter-v28b.psf.gz";
  };
  
  i18n.defaultLocale = "en_US.UTF-8";

  hardware.enableRedistributableFirmware = true;
  hardware.bluetooth.enable = true;

  hardware.graphics = {
    enable = true;
    extraPackages = with pkgs; [
      intel-media-driver
      vpl-gpu-rt
    ];
  };

  hardware.nvidia = {
    package = config.boot.kernelPackages.nvidiaPackages.stable;
    open = true;
    nvidiaSettings = true;
  };

  hardware.nvidia.prime = {
    intelBusId = "PCI:0:2:0";
    nvidiaBusId = "PCI:2:0:0";
  };

  fonts.packages = with pkgs; [
    apple-fonts.sf-pro
    noto-fonts-cjk-sans
    noto-fonts-color-emoji
    (iosevka.override {
      set = "cavalier";

      privateBuildPlan = {
        family = "Iosevka Cavalier";
        spacing = "normal";
        serifs = "sans";
        noCvSs = false;
        exportGlyphNames = true;

        variants.inherits = "ss08";

        variants.weights.Regular = {
          shape = 400;
          menu = 400;
          css = 400;
        };

        variants.weights.Bold = {
          shape = 700;
          menu = 700;
          css = 700;
        };

        variants.weights.Italic = {
          angle = 9.4;
          shape = "italic";
          menu = "italic";
          css = "italic";
        };

        variants.weights.Upright = {
          angle = 0;
          shape = "upright";
          menu = "upright";
          css = "upright";
        };
      };
    })
  ];

  environment.sessionVariables = {
    LIBVA_DRIVER_NAME = "iHD";
    VDPAU_DRIVER = "va_gl";
  };

  nix.settings = {
    substituters = [ "https://cache.nixos-cuda.org" ];
    trusted-public-keys = [ "cache.nixos-cuda.org:74DUi4Ye579gUqzH4ziL9IyiJBlDpMRn9MBN8oNan9M=" ];
  };

  nixpkgs.config.allowUnfreePredicate =
    pkg:
    builtins.elem (lib.getName pkg) [
      "1password"
      "1password-cli"
      "nvidia-x11"
      "nvidia-settings"
    ];

  programs._1password.enable = true;

  services.pipewire.enable = true;

  services.xserver.videoDrivers = [
    "modesetting"
    "nvidia"
  ];

  time.timeZone = "Europe/Paris";

  users.users.pml = {
    isNormalUser = true;
    shell = pkgs.zsh;
    extraGroups = [
      "i2c"
      "wheel"
    ];
    packages = with pkgs; [
      (vscode-with-extensions.override {
        vscode = vscodium;
        vscodeExtensions = with vscode-extensions; [
          jnoortheen.nix-ide
          mkhl.direnv
          yzhang.markdown-all-in-one
        ];
      })
    ];
  };

  # DO NOT EDIT
  system.stateVersion = "25.05";
}